!!! Plošný model struktury B o rozměru NxN buněk !!!

FINISH
/CLEAR

*ABBR,INPUT,'/INPUT,strukturaB_NxN,txt'    


!!!!!!!!!!!!!!!!!!!
!!! PREPROCESOR !!!
!!!!!!!!!!!!!!!!!!!

/PREP7
       
*AFUN,DEG            

!!! Vstupni parametry !!!
L=10			! delka L [mm]
alfa=30			! uhel alfa [°]
beta=60			! uhel beta [°]
T=0.5			! tloustka [mm]
Fappl=1			! zatezna sila [N]
Emod=200000		! modul pruznosti v tahu zakladniho materialu [MPa]
nu=0.3			! Poissonuv pomer zakladniho materialu [-]
N=5			! pocet bunek v obou smerech [-]
ELSIZE=0.5		! velikost prvku [mm]


SELTOL,1e-6		! automaticke nastaveni potrebnych parametru
TH=1
beta=90-beta

!!! Definice elementu !!!
ET,1,PLANE183

!!! Definice materialu !!!
MP,EX,1,Emod
MP,PRXY,1,,nu

!!! Tvorba geometrie !!!

	!!!Referencni geometrie !!!
!K,10,0,L*cos(alfa),0
!K,20,L*sin(alfa),0,0
!K,30,0,L*sin(alfa)*tan(beta)
!K,40,-L*sin(alfa),0,0

!L,10,20	$	L,20,30	$	L,30,40	$	L,40,10

	!!! Vnitrni geometrie !!!
K,1,0,L*cos(alfa)-(T/2)/sin(alfa),0
K,2,L*sin(alfa)-T/(2*sin((90-alfa-beta)/2))*cos((90-alfa+beta)/2),T/(2*sin((90-alfa-beta)/2))*sin((90-alfa+beta)/2),0
K,3,0,L*sin(alfa)*tan(beta)+(T/2)/cos(beta),0
K,4,-L*sin(alfa)+T/(2*sin((90-alfa-beta)/2))*cos((90-alfa+beta)/2),T/(2*sin((90-alfa-beta)/2))*sin((90-alfa+beta)/2),0

L,1,2	$	L,2,3	$	L,3,4	$	L,4,1	


	!!! Vnejsi geometrie !!!
K,11,0,L*cos(alfa)+(T/2)/sin(alfa)-(T/2)*(1/sin(alfa)-1/cos(beta)),0
K,1112,(T*sin(alfa)*(1/sin(alfa)-1/cos(beta)))/(2*(cos(alfa)-sin(alfa)*tan(beta))),L*cos(alfa)+(T/2)/sin(alfa)-(T*cos(alfa)*(1/sin(alfa)-1/cos(beta)))/(2*(cos(alfa)-sin(alfa)*tan(beta)))
K,12,L*sin(alfa),(T/2)/sin(alfa)
K,22,L*sin(alfa),-(T/2)/cos(beta),0
K,33,0,L*sin(alfa)*tan(beta)-(T/2)/cos(beta),0
K,34,-L*sin(alfa),-(T/2)/cos(beta),0
K,44,-L*sin(alfa),(T/2)/sin(alfa),0
K,4411,-(T*sin(alfa)*(1/sin(alfa)-1/cos(beta)))/(2*(cos(alfa)-sin(alfa)*tan(beta))),L*cos(alfa)+(T/2)/sin(alfa)-(T*cos(alfa)*(1/sin(alfa)-1/cos(beta)))/(2*(cos(alfa)-sin(alfa)*tan(beta)))

L,11,1112	$	L,1112,12	$	L,12,22	$	L,22,33	$	L,33,34	$	L,34,44	$	L,44,4411	$	L,4411,11

LSEL,ALL
LPLOT

!!! Vytvoreni struktury !!!
	
	!!! Zakladni struktura !!!
LSEL,ALL
AL,ALL

ASEL,ALL
AGEN,N,ALL,,,2*L*sin(alfa),0,0,,0

ASEL,ALL
AGEN,N,ALL,,,,L*(cos(alfa)-sin(alfa)*tan(beta)),0,,0
AADD,ALL

!!! Vytvoreni site !!!
!HPTCREATE,AREA,1,,COORD,0,L*cos(alfa),0
ESIZE,ELSIZE
AATT,1,,1
AMESH,ALL

NUMMRG,NODE,0.000001
NUMMRG,KP,0.000001

!!! Okrajove podminky !!!
*DO,step,1,N
NSEL,S,LOC,Y,L*sin(alfa)*tan(beta)-(T/2)/cos(beta)									
NSEL,R,LOC,X,(step-1)*2*L*sin(alfa)																					$	D,ALL,UY,0	
*ENDDO			
NSEL,S,LOC,X,-L*sin(alfa)																							$	D,ALL,UX,0
NSEL,S,LOC,X,(2*N-1)*L*sin(alfa)																					$	CP,1,UX,ALL
NSEL,S,LOC,Y,L*cos(alfa)+(N-1)*(L*cos(alfa)-L*sin(alfa)*tan(beta))+(T/2)/sin(alfa)-(T/2)*(1/sin(alfa)-1/cos(beta))	$	CP,2,UY,ALL

ALLSEL,ALL

!!! Zatizeni !!!
NSEL,S,LOC,Y,L*cos(alfa)+(N-1)*(L*cos(alfa)-L*sin(alfa)*tan(beta))+(T/2)/sin(alfa)-(T/2)*(1/sin(alfa)-1/cos(beta))	$	NSEL,R,LOC,X,0
!NSEL,S,LOC,Y,L*cos(alfa)	$	LSEL,R,LOC,X,0
!NSEL,S,LOC,Y,L*cos(alfa)-(T/2)/sin(alfa)	$	NSEL,R,LOC,X,0
F,ALL,FY,Fappl

ALLSEL,ALL


!!!!!!!!!!!!!!!!
!!! SOLUTION !!!
!!!!!!!!!!!!!!!!
	
/SOLU

EQSLV,PCG,1e-8	
	
SOLVE


!!!!!!!!!!!!!!!!!!!!!
!!! POSTPROCESSOR !!!
!!!!!!!!!!!!!!!!!!!!!

/POST1

!!! Zjisteni posuvu ve smeru x !!!
NSEL,S,LOC,X,(2*N-1)*L*sin(alfa)
*GET,minnode1,NODE,0,NUM,MIN
*GET,UXdisp,NODE,minnode1,U,X

!!! Zjisteni posuvu ve smeru y !!!
NSEL,S,LOC,Y,L*cos(alfa)+(N-1)*(L*cos(alfa)-L*sin(alfa)*tan(beta))+(T/2)/sin(alfa)-(T/2)*(1/sin(alfa)-1/cos(beta))	$	NSEL,R,LOC,X,0	!L*cos(alfa)+(N-1)*(L*cos(alfa)-L*sin(alfa)*tan(beta))+(T/2)/sin(alfa)-(T/2)*(1/sin(alfa)-1/cos(beta))	
*GET,minnode3,NODE,0,NUM,MIN
*GET,UYdisp,NODE,minnode3,U,Y

!!! Vypocet Poissonova pomeru !!!
X0=N*2*L*sin(alfa)
Y0=(L*cos(alfa)-(L*sin(alfa)*tan(beta)))*N

!Y0=L*cos(alfa)+(N-1)*(L*cos(alfa)-L*sin(alfa)*tan(beta))+(T/2)/sin(alfa)-(T/2)*(1/sin(alfa)-1/cos(beta))+(T/2)/cos(beta)

epsX=UXdisp/X0
epsY=UYdisp/Y0

nuCALC=-epsX/epsY				! hodnota vysledneho Poissonova pomeru [-]

!!! Urceni plochy bunek !!!
S=X0*TH

!!! Vypocet E !!!
sigma=Fappl/S
Ecalc=abs(sigma/epsY)/Emod		! hodnota vysledneho pomerneho modulu pruznosti v tahu [-]